Aufgabe:
Man erstelle einen Aufgabengenerator, der verschiedene Aufgaben zu Symmetrieachse und Scheitelpunkt einer Parabel erzeugt. Die Parabel ist durch 3 Punkte gegeben. Der Scheitelwert wird als Ergebnis einer Extremwertaufgabe ermittelt.
Code:
x1:3$y1:4$
x2:1$y2:-5$
x3:5$y3:4 /* Die Eingaben können verändert werden */$
g(x,y):=y=a*x^2+b*x+c$
g1:g(x1,y1)$g2:g(x2,y2)$g3:g(x3,y3)$
l:solve([g1,g2,g3],[a,b,c])$
Funktion:g(x,y),l$
f:rhs(Funktion)$
f(x):=''f$
ab:diff(f(x),x)$
l:solve(ab=0,x)$
xE:ev(x,l)$yE:f(xE)$
Scheitelpunkt:[xE,yE]$
Symmetrieachse:l$
print(" ")$print("Aufgabe und Lösung")$print(" ")$
Zum_Austeilen:matrix(["Gegebene Punkte",[[x1,y1],[x2,y2],[x3,y3]]],
["Errechnete Parabel",Funktion],
["Der Scheitelpunkt ist",Scheitelpunkt],["Die Symmetrieachse ist",Symmetrieachse])$
disp(Zum_Austeilen)$
Wenn man die Eingabedaten verändert, wird eine andere Aufgabenstellung generiert.
Dokumentation:
| CODE | Erklärung |
| x1:3$y1:4$ | A(3,4) |
| x2:1$y2:-5$ | B(2,-5) |
| x3:5$y3:4 /* Die Eingaben können verändert werden */$ | C(5,4) |
| g(x,y):=y=a*x^2+b*x+c$ | Ansatz quadratische Funktion |
| g1:g(x1,y1)$g2:g(x2,y2)$g3:g(x3,y3)$ | Koordinaten der Punkte einsetzen |
| l:solve([g1,g2,g3],[a,b,c])$ | 3 lineare Gleichungen mit 3 Unbekannten lösen |
| Funktion:g(x,y),l$ | Ergebnis einsetzen |
| f:rhs(Funktion)$ | Rechte Seite der quadratischen Funktion (Funktionsterm) |
| f(x):=“f$ | f(x) erstellen |
| ab:diff(f(x),x)$ | Erste Ableitung von f(x) |
| l:solve(ab=0,x)$ | Erste Ableitung NULL setzen (notwendige Bedingung) |
| xE:ev(x,l)$yE:f(xE)$ | Koordinaten des Extremwerts |
| Scheitelpunkt:[xE,yE]$ | Koordinaten einem Punkt zuweisen (Liste) |
| Symmetrieachse:l$ | Die Symmetrieachse ist der x-Wert des Scheitelpunktes |
| print(“ „)$print(„Aufgabe und Lösung“)$print(“ „)$ | Aufgabe zusammenstellen |
| Zum_Austeilen:matrix([„Gegebene Punkte“,[[x1,y1],[x2,y2],[x3,y3]]], | |
| [„Errechnete Parabel“,Funktion], | |
| [„Der Scheitelpunkt ist“,Scheitelpunkt],[„Die Symmetrieachse ist“,Symmetrieachse])$ | |
| disp(Zum_Austeilen)$ | Aufgabe zum Ausdrucken |
wxMaxima:
